/*
  --- dqm provenance ---
  Upstream: SupplementalDataElements 5.1.000
  Source package: CMS165FHIR-v1.0.000 (2026-05-14)
  Port date: 2026-09-21
  Kind: reimplementation
  Divergences: input/cql/dqm-divergence-registry.json
  ---

  India supplemental data (§5). Sex and Payer have analogues.
  State/district + urban-rural replace US Core race/ethnicity.
*/
library AtriusSupplementalDataElements version '0.1.0'

using FHIR version '4.0.1'
using AtriusIn version '0.1.0'

include FHIRHelpers version '4.4.000' called FHIRHelpers

codesystem "SNOMEDCT": 'http://snomed.info/sct'

valueset "Payer Type": 'https://atrius.in/fhir/r4/atrius-in/ValueSet/atrius-in-coverage-type'

code "Male (finding)": '248153007' from "SNOMEDCT" display 'Male'
code "Female (finding)": '248152002' from "SNOMEDCT" display 'Female'

context Patient

define "Preferred Address":
  Coalesce(
    First(Patient.address A
        where A.use = 'home'
    ),
    First(Patient.address)
  )

define "SDE Sex":
  case
    when Patient.gender = 'male' then "Male (finding)"
    when Patient.gender = 'female' then "Female (finding)"
    else null
  end

define "SDE Payer":
  [Coverage: "Payer Type"] Payer
    return {
      code: Payer.type,
      period: Payer.period
    }

define "SDE Residence":
  "Preferred Address" A
    return Tuple {
      state: A.state,
      district: A.district
    }

define "SDE Urban Rural":
  "Preferred Address" A
    return singleton from (
      A.extension E
        where E.url = 'https://atrius.in/fhir/r4/atrius-in/StructureDefinition/atrius-in-address-urban-rural'
        return E.value as FHIR.Coding
    )

Encoded data 

Encoded data